e8a6597957
* [R] fix predict contributions for data with no colnames * [R] add a render parameter for xgb.plot.multi.trees; fixes #2628 * [R] update Rd's * [R] remove unnecessary dep-package from R cmake install * silence type warnings; readability * [R] silence complaint about incomplete line at the end * [R] initial version of xgb.plot.shap() * [R] more work on xgb.plot.shap * [R] enforce black font in xgb.plot.tree; fixes #2640 * [R] if feature names are available, check in predict that they are the same; fixes #2857 * [R] cran check and lint fixes * remove tabs * [R] add references; a test for plot.shap
87 lines
3.4 KiB
CMake
87 lines
3.4 KiB
CMake
|
|
# Automatically set source group based on folder
|
|
function(auto_source_group SOURCES)
|
|
|
|
foreach(FILE ${SOURCES})
|
|
get_filename_component(PARENT_DIR "${FILE}" PATH)
|
|
|
|
# skip src or include and changes /'s to \\'s
|
|
string(REPLACE "${CMAKE_CURRENT_LIST_DIR}" "" GROUP "${PARENT_DIR}")
|
|
string(REPLACE "/" "\\\\" GROUP "${GROUP}")
|
|
string(REGEX REPLACE "^\\\\" "" GROUP "${GROUP}")
|
|
|
|
source_group("${GROUP}" FILES "${FILE}")
|
|
endforeach()
|
|
endfunction(auto_source_group)
|
|
|
|
# Force static runtime for MSVC
|
|
function(msvc_use_static_runtime)
|
|
if(MSVC)
|
|
set(variables
|
|
CMAKE_CXX_FLAGS_DEBUG
|
|
CMAKE_CXX_FLAGS_MINSIZEREL
|
|
CMAKE_CXX_FLAGS_RELEASE
|
|
CMAKE_CXX_FLAGS_RELWITHDEBINFO
|
|
)
|
|
foreach(variable ${variables})
|
|
if(${variable} MATCHES "/MD")
|
|
string(REGEX REPLACE "/MD" "/MT" ${variable} "${${variable}}")
|
|
set(${variable} "${${variable}}" PARENT_SCOPE)
|
|
endif()
|
|
endforeach()
|
|
endif()
|
|
endfunction(msvc_use_static_runtime)
|
|
|
|
# Set output directory of target, ignoring debug or release
|
|
function(set_output_directory target dir)
|
|
set_target_properties(${target} PROPERTIES
|
|
RUNTIME_OUTPUT_DIRECTORY ${dir}
|
|
RUNTIME_OUTPUT_DIRECTORY_DEBUG ${dir}
|
|
RUNTIME_OUTPUT_DIRECTORY_RELEASE ${dir}
|
|
LIBRARY_OUTPUT_DIRECTORY ${dir}
|
|
LIBRARY_OUTPUT_DIRECTORY_DEBUG ${dir}
|
|
LIBRARY_OUTPUT_DIRECTORY_RELEASE ${dir}
|
|
)
|
|
endfunction(set_output_directory)
|
|
|
|
# Set a default build type to release if none was specified
|
|
function(set_default_configuration_release)
|
|
if(CMAKE_CONFIGURATION_TYPES STREQUAL "Debug;Release;MinSizeRel;RelWithDebInfo") # multiconfig generator?
|
|
set(CMAKE_CONFIGURATION_TYPES Release CACHE STRING "" FORCE)
|
|
elseif(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
|
|
message(STATUS "Setting build type to 'Release' as none was specified.")
|
|
set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build." FORCE )
|
|
endif()
|
|
endfunction(set_default_configuration_release)
|
|
|
|
function(format_gencode_flags flags out)
|
|
foreach(ver ${flags})
|
|
set(${out} "${${out}}-gencode arch=compute_${ver},code=sm_${ver};")
|
|
endforeach()
|
|
set(${out} "${${out}}" PARENT_SCOPE)
|
|
endfunction(format_gencode_flags flags)
|
|
|
|
# Assembles the R-package files in build_dir;
|
|
# if necessary, installs the main R package dependencies;
|
|
# runs R CMD INSTALL.
|
|
function(setup_rpackage_install_target rlib_target build_dir)
|
|
install(CODE "file(REMOVE_RECURSE \"${build_dir}/R-package\")")
|
|
install(
|
|
DIRECTORY "${PROJECT_SOURCE_DIR}/R-package"
|
|
DESTINATION "${build_dir}"
|
|
REGEX "src/*" EXCLUDE
|
|
REGEX "R-package/configure" EXCLUDE
|
|
)
|
|
install(TARGETS ${rlib_target}
|
|
LIBRARY DESTINATION "${build_dir}/R-package/src/"
|
|
RUNTIME DESTINATION "${build_dir}/R-package/src/")
|
|
install(CODE "file(WRITE \"${build_dir}/R-package/src/Makevars\" \"all:\")")
|
|
install(CODE "file(WRITE \"${build_dir}/R-package/src/Makevars.win\" \"all:\")")
|
|
set(XGB_DEPS_SCRIPT
|
|
"deps = setdiff(c('data.table', 'magrittr', 'stringi'), rownames(installed.packages()));\
|
|
if(length(deps)>0) install.packages(deps, repo = 'https://cloud.r-project.org/')")
|
|
install(CODE "execute_process(COMMAND \"${LIBR_EXECUTABLE}\" \"-q\" \"-e\" \"${XGB_DEPS_SCRIPT}\")")
|
|
install(CODE "execute_process(COMMAND \"${LIBR_EXECUTABLE}\" CMD INSTALL\
|
|
\"--no-multiarch\" \"${build_dir}/R-package\")")
|
|
endfunction(setup_rpackage_install_target)
|