9adb812a0a
* [CI] Add RMM as an optional dependency * Replace caching allocator with pool allocator from RMM * Revert "Replace caching allocator with pool allocator from RMM" This reverts commit e15845d4e72e890c2babe31a988b26503a7d9038. * Use rmm::mr::get_default_resource() * Try setting default resource (doesn't work yet) * Allocate pool_mr in the heap * Prevent leaking pool_mr handle * Separate EXPECT_DEATH() in separate test suite suffixed DeathTest * Turn off death tests for RMM * Address reviewer's feedback * Prevent leaking of cuda_mr * Fix Jenkinsfile syntax * Remove unnecessary function in Jenkinsfile * [CI] Install NCCL into RMM container * Run Python tests * Try building with RMM, CUDA 10.0 * Do not use RMM for CUDA 10.0 target * Actually test for test_rmm flag * Fix TestPythonGPU * Use CNMeM allocator, since pool allocator doesn't yet support multiGPU * Use 10.0 container to build RMM-enabled XGBoost * Revert "Use 10.0 container to build RMM-enabled XGBoost" This reverts commit 789021fa31112e25b683aef39fff375403060141. * Fix Jenkinsfile * [CI] Assign larger /dev/shm to NCCL * Use 10.2 artifact to run multi-GPU Python tests * Add CUDA 10.0 -> 11.0 cross-version test; remove CUDA 10.0 target * Rename Conda env rmm_test -> gpu_test * Use env var to opt into CNMeM pool for C++ tests * Use identical CUDA version for RMM builds and tests * Use Pytest fixtures to enable RMM pool in Python tests * Move RMM to plugin/CMakeLists.txt; use PLUGIN_RMM * Use per-device MR; use command arg in gtest * Set CMake prefix path to use Conda env * Use 0.15 nightly version of RMM * Remove unnecessary header * Fix a unit test when cudf is missing * Add RMM demos * Remove print() * Use HostDeviceVector in GPU predictor * Simplify pytest setup; use LocalCUDACluster fixture * Address reviewers' commments Co-authored-by: Hyunsu Cho <chohyu01@cs.wasshington.edu>
97 lines
3.0 KiB
CMake
97 lines
3.0 KiB
CMake
if (USE_DMLC_GTEST)
|
|
if (NOT TARGET gtest)
|
|
message(FATAL_ERROR "USE_DMLC_GTEST=ON but dmlc-core didn't bundle gtest")
|
|
endif (NOT TARGET gtest)
|
|
set(GTEST_LIBRARIES gtest)
|
|
else (USE_DMLC_GTEST)
|
|
find_package(GTest REQUIRED)
|
|
endif (USE_DMLC_GTEST)
|
|
file(GLOB_RECURSE TEST_SOURCES "*.cc")
|
|
|
|
if (USE_CUDA)
|
|
file(GLOB_RECURSE CUDA_TEST_SOURCES "*.cu")
|
|
list(APPEND TEST_SOURCES ${CUDA_TEST_SOURCES})
|
|
endif (USE_CUDA)
|
|
|
|
file(GLOB_RECURSE ONEAPI_TEST_SOURCES "plugin/*_oneapi.cc")
|
|
if (NOT PLUGIN_UPDATER_ONEAPI)
|
|
list(REMOVE_ITEM TEST_SOURCES ${ONEAPI_TEST_SOURCES})
|
|
endif (NOT PLUGIN_UPDATER_ONEAPI)
|
|
|
|
add_executable(testxgboost ${TEST_SOURCES}
|
|
${xgboost_SOURCE_DIR}/plugin/example/custom_obj.cc)
|
|
target_link_libraries(testxgboost PRIVATE objxgboost)
|
|
|
|
if (USE_CUDA)
|
|
# OpenMP is mandatory for CUDA
|
|
find_package(OpenMP REQUIRED)
|
|
if (CMAKE_CUDA_COMPILER_VERSION VERSION_LESS 11.0)
|
|
target_include_directories(testxgboost PRIVATE
|
|
${xgboost_SOURCE_DIR}/cub/)
|
|
endif (CMAKE_CUDA_COMPILER_VERSION VERSION_LESS 11.0)
|
|
target_compile_options(testxgboost PRIVATE
|
|
$<$<COMPILE_LANGUAGE:CUDA>:--expt-extended-lambda>
|
|
$<$<COMPILE_LANGUAGE:CUDA>:--expt-relaxed-constexpr>
|
|
$<$<COMPILE_LANGUAGE:CUDA>:-lineinfo>
|
|
$<$<COMPILE_LANGUAGE:CUDA>:-Xcompiler=${OpenMP_CXX_FLAGS}>
|
|
$<$<COMPILE_LANGUAGE:CUDA>:${GEN_CODE}>)
|
|
target_compile_definitions(testxgboost
|
|
PRIVATE -DXGBOOST_USE_CUDA=1)
|
|
find_package(CUDA)
|
|
target_include_directories(testxgboost PRIVATE ${CUDA_INCLUDE_DIRS})
|
|
set_target_properties(testxgboost PROPERTIES
|
|
CUDA_SEPARABLE_COMPILATION OFF)
|
|
|
|
if (USE_NCCL)
|
|
find_package(Nccl REQUIRED)
|
|
target_include_directories(testxgboost PRIVATE ${NCCL_INCLUDE_DIR})
|
|
target_compile_definitions(testxgboost PRIVATE -DXGBOOST_USE_NCCL=1)
|
|
target_link_libraries(testxgboost PRIVATE ${NCCL_LIBRARY})
|
|
endif (USE_NCCL)
|
|
|
|
if (USE_NVTX)
|
|
enable_nvtx(testxgboost)
|
|
endif (USE_NVTX)
|
|
|
|
if (MSVC)
|
|
target_compile_options(testxgboost PRIVATE
|
|
$<$<COMPILE_LANGUAGE:CUDA>:-Xcompiler=/utf-8>
|
|
)
|
|
endif (MSVC)
|
|
|
|
set_target_properties(testxgboost PROPERTIES
|
|
CUDA_STANDARD 14
|
|
CUDA_STANDARD_REQUIRED ON)
|
|
endif (USE_CUDA)
|
|
|
|
if (MSVC)
|
|
target_compile_options(testxgboost PRIVATE
|
|
$<$<NOT:$<COMPILE_LANGUAGE:CUDA>>:/utf-8>
|
|
-D_CRT_SECURE_NO_WARNINGS
|
|
-D_CRT_SECURE_NO_DEPRECATE
|
|
)
|
|
endif (MSVC)
|
|
if (ENABLE_ALL_WARNINGS)
|
|
target_compile_options(testxgboost PUBLIC
|
|
$<IF:$<COMPILE_LANGUAGE:CUDA>,-Xcompiler=-Wall -Xcompiler=-Wextra,-Wall -Wextra>)
|
|
endif (ENABLE_ALL_WARNINGS)
|
|
|
|
target_include_directories(testxgboost
|
|
PRIVATE
|
|
${GTEST_INCLUDE_DIRS}
|
|
${xgboost_SOURCE_DIR}/include
|
|
${xgboost_SOURCE_DIR}/dmlc-core/include
|
|
${xgboost_SOURCE_DIR}/rabit/include)
|
|
set_target_properties(
|
|
testxgboost PROPERTIES
|
|
CXX_STANDARD 14
|
|
CXX_STANDARD_REQUIRED ON)
|
|
target_link_libraries(testxgboost
|
|
PRIVATE
|
|
${GTEST_LIBRARIES})
|
|
|
|
set_output_directory(testxgboost ${xgboost_BINARY_DIR})
|
|
|
|
# This grouping organises source files nicely in visual studio
|
|
auto_source_group("${TEST_SOURCES}")
|